git.ozlabs.org Git - petitboot/blob - configure.ac

   1 ## configure.ac -- Process this file with autoconf to produce configure
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; version 2 of the License.
   6 #
   7 #  This program is distributed in the hope that it will be useful,
   8 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
   9 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10 #  GNU General Public License for more details.
  11 #
  12 #  You should have received a copy of the GNU General Public License
  13 #  along with this program; if not, write to the Free Software
  14 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  15 #
  16
  17 AC_INIT([petitboot],
  18     [m4_esyscmd_s([./version.sh])],
  19     [Geoff Levand <geoff@infradead.org>])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PREFIX_DEFAULT([/usr/local])
  24
  25 AS_IF([test "x$CFLAGS" = "x"], [AC_SUBST([CFLAGS], [""])])
  26
  27 AC_PROG_CC
  28 AC_PROG_LEX
  29 AC_PROG_YACC
  30 AC_PROG_INSTALL
  31
  32 AM_INIT_AUTOMAKE
  33 AC_GNU_SOURCE
  34 AM_GNU_GETTEXT([external])
  35 AM_GNU_GETTEXT_VERSION(0.18.1)
  36 LT_INIT
  37
  38 AM_SILENT_RULES([yes])
  39
  40 AX_WITH_CURSES
  41 AX_WITH_CURSES_MENU
  42 AX_WITH_CURSES_FORM
  43
  44 AM_CONDITIONAL([WITH_NCURSES], [test "x$ax_cv_curses" = "xyes"])
  45
  46 if test "x$ax_cv_curses" = xyes; then
  47         if test "x$ax_cv_menu" != xyes; then
  48                 AC_MSG_ERROR([--with-ncurses requires the ncurses menu library])
  49         fi
  50         if test "x$ax_cv_form" != xyes; then
  51                 AC_MSG_ERROR([--with-ncurses requires the ncurses form library])
  52         fi
  53 fi
  54
  55 AC_CHECK_LIB([udev], [udev_new],
  56         [UDEV_LIBS=-ludev],
  57         [AC_MSG_FAILURE([The libudev development library is required by petitboot.  Try installing the package libudev-dev or libudev-devel.])]
  58 )
  59
  60 AC_CHECK_HEADERS([stdarg.h])
  61 AC_CHECK_HEADERS([varargs.h])
  62
  63 dnl Checking for va_copy availability
  64 AC_MSG_CHECKING([for va_copy])
  65 AC_TRY_LINK([#include <stdarg.h>
  66 va_list ap1,ap2;], [va_copy(ap1,ap2);],
  67 have_va_copy=yes,
  68 have_va_copy=no)
  69 AC_MSG_RESULT($have_va_copy)
  70 if test x"$have_va_copy" = x"yes"; then
  71     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
  72 else
  73     AC_MSG_CHECKING([for __va_copy])
  74     AC_TRY_LINK([#include <stdarg.h>
  75     va_list ap1,ap2;], [__va_copy(ap1,ap2);],
  76     have___va_copy=yes,
  77     have___va_copy=no)
  78     AC_MSG_RESULT($have___va_copy)
  79     if test x"$have___va_copy" = x"yes"; then
  80         AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
  81     fi
  82 fi
  83
  84 AC_ARG_WITH(
  85         [twin-x11],
  86         [AS_HELP_STRING([--with-twin-x11],
  87                 [build x11 GUI programs using the twin window system [default=yes]]
  88         )],
  89         [],
  90         [with_twin_x11=yes]
  91 )
  92 AM_CONDITIONAL([WITH_TWIN_X11], [test "x$with_twin_x11" = "xyes"])
  93
  94 AC_ARG_WITH(
  95         [twin-fbdev],
  96         [AS_HELP_STRING(
  97                 [--with-twin-fbdev],
  98                 [build frame buffer GUI programs using the twin window system [default=no]]
  99         )],
 100         [],
 101         [with_twin_fbdev=yes]
 102 )
 103 AM_CONDITIONAL([WITH_TWIN_FBDEV], [test "x$with_twin_fbdev" = "xyes"])
 104
 105 AM_CONDITIONAL(
 106         [WITH_TWIN],
 107         [test "x$with_twin_x11" = "xyes" || test "x$with_twin_fbdev" = "xyes"])
 108
 109 AS_IF(
 110         [test "x$with_twin_x11" = "xyes" || test "x$with_twin_fbdev" = "xyes"],
 111         [PKG_CHECK_MODULES(
 112                 [twin],
 113                 [libtwin],
 114                 [SAVE_LIBS="$LIBS" LIBS="$LIBS $twin_LIBS"
 115                         AC_CHECK_LIB(
 116                                 [twin],
 117                                 [twin_feature_init],
 118                                 [],
 119                                 [AC_MSG_FAILURE([--with-twin was given but the test for libtwin failed.])]
 120                         )
 121                         LIBS="$SAVE_LIBS"
 122                 ],
 123                 [AC_MSG_RESULT([$twin_PKG_ERRORS])
 124                         AC_MSG_FAILURE([ Consider adjusting PKG_CONFIG_PATH environment variable])
 125                 ]
 126         )]
 127 )
 128
 129 AS_IF(
 130         [test "x$with_twin_x11" = "xyes"],
 131         [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $twin_CFLAGS"
 132                 AC_CHECK_HEADERS(
 133                         [libtwin/twin_x11.h],
 134                         [],
 135                         [AC_MSG_FAILURE([ --with-twin-x11 given but libtwin/twin_x11.h not found])]
 136                 )
 137                 CPPFLAGS="$SAVE_CPPFLAGS"
 138         ]
 139 )
 140
 141 AS_IF(
 142         [test "x$with_twin_fbdev" = "xyes"],
 143         [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $twin_CFLAGS"
 144                 AC_CHECK_HEADERS(
 145                         [libtwin/twin_fbdev.h],
 146                         [],
 147                         [AC_MSG_FAILURE([ --with-twin-fbdev given but libtwin/twin_fbdev.h not found])]
 148                 )
 149                 CPPFLAGS="$SAVE_CPPFLAGS"
 150         ]
 151 )
 152
 153 AC_ARG_ENABLE(
 154         [busybox],
 155         [AS_HELP_STRING(
 156                 [--enable-busybox],
 157                 [build programs with extra support for busybox [default=no]])
 158         ],
 159         [],
 160         [enable_busybox=no]
 161 )
 162 #AM_CONDITIONAL([ENABLE_BUSYBOX], [test "x$enable_busybox" = "xyes"])
 163
 164 AC_ARG_ENABLE(
 165         [mtd],
 166         [AS_HELP_STRING(
 167                 [--enable-mtd],
 168                 [Add support for MTD devices on certain platforms [default=no]]
 169         )],
 170         [],
 171         [enable_mtd=no]
 172 )
 173 AM_CONDITIONAL([ENABLE_MTD], [test "x$enable_mtd" = "xyes"])
 174 AS_IF([test "x$enable_mtd" = "xyes"],
 175       [AC_DEFINE(MTD_SUPPORT, 1, [Enable MTD support])],
 176       []
 177 )
 178
 179 AC_ARG_ENABLE(
 180         [ps3],
 181         [AS_HELP_STRING(
 182                 [--enable-ps3],
 183                 [build additional programs for the PS3 game console [default=no]]
 184         )],
 185         [],
 186         [enable_ps3=no]
 187 )
 188 AM_CONDITIONAL([ENABLE_PS3], [test "x$enable_ps3" = "xyes"])
 189
 190 AC_ARG_ENABLE(
 191         [debug],
 192         [AS_HELP_STRING([--enable-debug],
 193                 [build programs with extra debug info [default=no]]
 194         )],
 195         [],
 196         [enable_debug=check]
 197 )
 198 #AM_CONDITIONAL([ENABLE_DEBUG], [test "x$enable_debug" = "xyes"])
 199
 200 AC_ARG_ENABLE(
 201         [test-valgrind],
 202         [AS_HELP_STRING([--enable-test-valgrind],
 203                 [run all tests with valgrind]
 204         )],
 205 )
 206 AM_CONDITIONAL([ENABLE_TEST_VALGRIND], [test "x$enable_test_valgrind" = "xyes"])
 207
 208 # host program paths
 209 AC_DEFUN([DEFINE_HOST_PROG],
 210         [
 211                 AC_ARG_VAR([HOST_PROG_$1], [Path to "$2" on the host [default $3]])
 212                 if test "x$HOST_PROG_$1" = "x"; then
 213                         HOST_PROG_$1="$3"
 214                 fi
 215                 AC_DEFINE_UNQUOTED(HOST_PROG_$1, ["$HOST_PROG_$1"],
 216                                 [Path to "$2" on the host])
 217         ])
 218
 219 DEFINE_HOST_PROG(CP, cp, [/bin/cp])
 220 DEFINE_HOST_PROG(KEXEC, kexec, [/sbin/kexec])
 221 DEFINE_HOST_PROG(MOUNT, mount, [/bin/mount])
 222 DEFINE_HOST_PROG(SHUTDOWN, shutdown, [/sbin/shutdown])
 223 DEFINE_HOST_PROG(SFTP, sftp, [/usr/bin/sftp])
 224 DEFINE_HOST_PROG(TFTP, tftp, [/usr/bin/tftp])
 225 DEFINE_HOST_PROG(UMOUNT, umount, [/bin/umount])
 226 DEFINE_HOST_PROG(WGET, wget, [/usr/bin/wget])
 227 DEFINE_HOST_PROG(IP, ip, [/sbin/ip])
 228 DEFINE_HOST_PROG(UDHCPC, udhcpc, [/sbin/udhcpc])
 229
 230 AC_ARG_WITH(
 231     [tftp],
 232     [AS_HELP_STRING([--with-tftp=TYPE],
 233         [Use TYPE-type ftp client (either hpa or busybox) [default=runtime-check]]
 234     )],
 235     [],
 236     [with_tftp=detect]
 237 )
 238
 239 case x$with_tftp in
 240 'xhpa')
 241     tftp_type='TFTP_TYPE_HPA'
 242     ;;
 243 'xbusybox')
 244     tftp_type='TFTP_TYPE_BUSYBOX'
 245     ;;
 246 *)
 247     tftp_type='TFTP_TYPE_UNKNOWN'
 248     ;;
 249 esac
 250
 251 AC_DEFINE_UNQUOTED(TFTP_TYPE, $tftp_type, [tftp client type])
 252
 253 default_cflags="--std=gnu99 -g \
 254         -Wall -W -Wunused -Wstrict-prototypes -Wmissing-prototypes \
 255         -Wmissing-declarations -Wredundant-decls"
 256
 257 AC_ARG_ENABLE(
 258         [werror],
 259         [AS_HELP_STRING([--enable-werror],
 260                 [build programs with -Werror]
 261         )],
 262         [default_cflags="$default_cflags -Werror"]
 263 )
 264
 265 AS_IF(
 266         [test "x$enable_debug" = "xyes"],
 267         [
 268                 AC_SUBST([DEFAULT_CFLAGS], ["$default_cflags -O0"])
 269                 AC_SUBST([DEFAULT_CPPFLAGS], ["-DDEBUG"])
 270         ],
 271         [
 272                 AC_SUBST([DEFAULT_CFLAGS], ["$default_cflags -O2"])
 273                 AC_SUBST([DEFAULT_CPPFLAGS], ["-DNDEBUG"])
 274         ]
 275 )
 276
 277 AC_SUBST([UDEV_LIBS])
 278 AC_SUBST([LIBTOOL_DEPS])
 279 AC_SUBST([DESTDIR])
 280 AC_SUBST([pkgsysconfdir], ["${sysconfdir}/${package}"])
 281
 282 AC_CONFIG_HEADERS([config.h])
 283 AC_CONFIG_FILES([
 284         Makefile
 285         po/Makefile.in
 286 ])
 287
 288 AC_OUTPUT