ui/ncurses: Add setlocale call
[petitboot] / configure.ac.in
1 ## configure.ac -- Process this file with autoconf to produce configure
2 #
3 #  This program is free software; you can redistribute it and/or modify
4 #  it under the terms of the GNU General Public License as published by
5 #  the Free Software Foundation; version 2 of the License.
6 #
7 #  This program is distributed in the hope that it will be useful,
8 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
9 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
10 #  GNU General Public License for more details.
11 #
12 #  You should have received a copy of the GNU General Public License
13 #  along with this program; if not, write to the Free Software
14 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
15 #
16
17 AC_INIT([petitboot], [@version@], [Geoff Levand <geoff@infradead.org>])
18
19 AC_CONFIG_MACRO_DIR([m4])
20
21 AC_PREFIX_DEFAULT([/usr/local])
22
23 AS_IF([test "x$CFLAGS" = "x"], [AC_SUBST([CFLAGS], [""])])
24
25 AC_PROG_CC
26 AC_PROG_INSTALL
27
28 AM_INIT_AUTOMAKE
29 LT_INIT
30
31 AC_CHECK_HEADERS([stdarg.h])
32 AC_CHECK_HEADERS([varargs.h])
33
34 AC_CHECK_LIB([udev], [udev_new],
35         [],
36         [AC_MSG_FAILURE([The libudev development library is required by petitboot.  Try installing the package libudev-dev or libudev-devel.])]
37 )
38
39 dnl Checking for va_copy availability
40 AC_MSG_CHECKING([for va_copy])
41 AC_TRY_LINK([#include <stdarg.h>
42 va_list ap1,ap2;], [va_copy(ap1,ap2);],
43 have_va_copy=yes,
44 have_va_copy=no)
45 AC_MSG_RESULT($have_va_copy)
46 if test x"$have_va_copy" = x"yes"; then
47     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
48 else
49     AC_MSG_CHECKING([for __va_copy])
50     AC_TRY_LINK([#include <stdarg.h>
51     va_list ap1,ap2;], [__va_copy(ap1,ap2);],
52     have___va_copy=yes,
53     have___va_copy=no)
54     AC_MSG_RESULT($have___va_copy)
55     if test x"$have___va_copy" = x"yes"; then
56         AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
57     fi
58 fi
59
60 AC_ARG_WITH(
61         [ncurses],
62         [AS_HELP_STRING([--with-ncurses],
63                 [build text console UI programs using ncurses [default=yes]]
64         )],
65         [],
66         [with_ncurses=yes]
67 )
68 AM_CONDITIONAL([WITH_NCURSES], [test "x$with_ncurses" = "xyes"])
69
70 AS_IF(
71         [test "x$with_ncurses" = "xyes"],
72         AC_CHECK_LIB([ncurses], [initscr],
73                 [],
74                 [AC_MSG_FAILURE([--with-ncurses was given but the test for libncurses failed.  Try installing the package ncurses-dev or ncurses-devel.])]
75         )
76 )
77
78 AC_ARG_WITH(
79         [twin-x11],
80         [AS_HELP_STRING([--with-twin-x11],
81                 [build x11 GUI programs using the twin window system [default=yes]]
82         )],
83         [],
84         [with_twin_x11=yes]
85 )
86 AM_CONDITIONAL([WITH_TWIN_X11], [test "x$with_twin_x11" = "xyes"])
87
88 AC_ARG_WITH(
89         [twin-fbdev],
90         [AS_HELP_STRING(
91                 [--with-twin-fbdev],
92                 [build frame buffer GUI programs using the twin window system [default=no]]
93         )],
94         [],
95         [with_twin_fbdev=yes]
96 )
97 AM_CONDITIONAL([WITH_TWIN_FBDEV], [test "x$with_twin_fbdev" = "xyes"])
98
99 AM_CONDITIONAL(
100         [WITH_TWIN],
101         [test "x$with_twin_x11" = "xyes" || test "x$with_twin_fbdev" = "xyes"])
102
103 AS_IF(
104         [test "x$with_twin_x11" = "xyes" || test "x$with_twin_fbdev" = "xyes"],
105         [PKG_CHECK_MODULES(
106                 [twin],
107                 [libtwin],
108                 [SAVE_LIBS="$LIBS" LIBS="$LIBS $twin_LIBS"
109                         AC_CHECK_LIB(
110                                 [twin],
111                                 [twin_feature_init],
112                                 [],
113                                 [AC_MSG_FAILURE([--with-twin was given but the test for libtwin failed.])]
114                         )
115                         LIBS="$SAVE_LIBS"
116                 ],
117                 [AC_MSG_RESULT([$twin_PKG_ERRORS])
118                         AC_MSG_FAILURE([ Consider adjusting PKG_CONFIG_PATH environment variable])
119                 ]
120         )]
121 )
122
123 AS_IF(
124         [test "x$with_twin_x11" = "xyes"],
125         [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $twin_CFLAGS"
126                 AC_CHECK_HEADERS(
127                         [libtwin/twin_x11.h],
128                         [],
129                         [AC_MSG_FAILURE([ --with-twin-x11 given but libtwin/twin_x11.h not found])]
130                 )
131                 CPPFLAGS="$SAVE_CPPFLAGS"
132         ]
133 )
134
135 AS_IF(
136         [test "x$with_twin_fbdev" = "xyes"],
137         [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $twin_CFLAGS"
138                 AC_CHECK_HEADERS(
139                         [libtwin/twin_fbdev.h],
140                         [],
141                         [AC_MSG_FAILURE([ --with-twin-fbdev given but libtwin/twin_fbdev.h not found])]
142                 )
143                 CPPFLAGS="$SAVE_CPPFLAGS"
144         ]
145 )
146
147 AC_ARG_ENABLE(
148         [busybox],
149         [AS_HELP_STRING(
150                 [--enable-busybox],
151                 [build programs with extra support for busybox [default=no]])
152         ],
153         [],
154         [enable_busybox=no]
155 )
156 #AM_CONDITIONAL([ENABLE_BUSYBOX], [test "x$enable_busybox" = "xyes"])
157
158 AC_ARG_ENABLE(
159         [ps3],
160         [AS_HELP_STRING(
161                 [--enable-ps3],
162                 [build additional programs for the PS3 game console [default=no]]
163         )],
164         [],
165         [enable_ps3=no]
166 )
167 AM_CONDITIONAL([ENABLE_PS3], [test "x$enable_ps3" = "xyes"])
168
169 AC_ARG_ENABLE(
170         [debug],
171         [AS_HELP_STRING([--enable-debug],
172                 [build programs with extra debug info [default=no]]
173         )],
174         [],
175         [enable_debug=check]
176 )
177 #AM_CONDITIONAL([ENABLE_DEBUG], [test "x$enable_debug" = "xyes"])
178
179 # host program paths
180 AC_DEFUN([DEFINE_HOST_PROG],
181         [
182                 AC_ARG_VAR([HOST_PROG_$1], [Path to "$2" on the host [default $3]])
183                 if test "x$HOST_PROG_$1" = "x"; then
184                         HOST_PROG_$1="$3"
185                 fi
186                 AC_DEFINE_UNQUOTED(HOST_PROG_$1, ["$HOST_PROG_$1"],
187                                 [Path to "$2" on the host])
188         ])
189
190 DEFINE_HOST_PROG(CP, cp, [/bin/cp])
191 DEFINE_HOST_PROG(KEXEC, kexec, [/sbin/kexec])
192 DEFINE_HOST_PROG(MOUNT, mount, [/bin/mount])
193 DEFINE_HOST_PROG(SHUTDOWN, shutdown, [/sbin/shutdown])
194 DEFINE_HOST_PROG(SFTP, sftp, [/usr/bin/sftp])
195 DEFINE_HOST_PROG(TFTP, tftp, [/usr/bin/tftp])
196 DEFINE_HOST_PROG(UMOUNT, umount, [/bin/umount])
197 DEFINE_HOST_PROG(WGET, wget, [/usr/bin/wget])
198 DEFINE_HOST_PROG(IP, ip, [/sbin/ip])
199 DEFINE_HOST_PROG(UDHCPC, udhcpc, [/sbin/udhcpc])
200
201 default_cflags="--std=gnu99 -g \
202         -Wall -W -Wunused -Wstrict-prototypes -Wmissing-prototypes \
203         -Wmissing-declarations -Wredundant-decls"
204
205 AC_ARG_ENABLE(
206         [werror],
207         [AS_HELP_STRING([--enable-werror],
208                 [build programs with -Werror]
209         )],
210         [default_cflags="$default_cflags -Werror"]
211 )
212
213 AS_IF(
214         [test "x$enable_debug" = "xyes"],
215         [AC_SUBST([DEFAULT_CFLAGS], ["$default_cflags -O0 -DDEBUG"])],
216         [AC_SUBST([DEFAULT_CFLAGS], ["$default_cflags -O2 -DNDEBUG"])]
217 )
218  
219
220 AC_SUBST([LIBTOOL_DEPS])
221 AC_SUBST([DESTDIR])
222 AC_SUBST([pkgsysconfdir], ["${sysconfdir}/${package}"])
223
224 AC_CONFIG_HEADERS([config.h])
225 AC_CONFIG_FILES([
226         Makefile
227         discover/Makefile
228         lib/Makefile
229         man/Makefile
230         test/Makefile
231         test/lib/Makefile
232         test/parser/Makefile
233         test/urls/Makefile
234         ui/Makefile
235         ui/common/Makefile
236         ui/ncurses/Makefile
237         ui/test/Makefile
238         ui/twin/Makefile
239         utils/Makefile
240 ])
241
242 AC_OUTPUT