m4/ax_check_openssl.m4

   1 # ===========================================================================
   2 #     http://www.gnu.org/software/autoconf-archive/ax_check_openssl.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CHECK_OPENSSL([action-if-found[, action-if-not-found]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Look for OpenSSL in a number of default spots, or in a user-selected
  12 #   spot (via --with-openssl).  Sets
  13 #
  14 #     OPENSSL_INCLUDES to the include directives required
  15 #     OPENSSL_LIBS to the -l directives required
  16 #     OPENSSL_LDFLAGS to the -L or -R flags required
  17 #
  18 #   and calls ACTION-IF-FOUND or ACTION-IF-NOT-FOUND appropriately
  19 #
  20 #   This macro sets OPENSSL_INCLUDES such that source files should use the
  21 #   openssl/ directory in include directives:
  22 #
  23 #     #include <openssl/hmac.h>
  24 #
  25 # LICENSE
  26 #
  27 #   Copyright (c) 2009,2010 Zmanda Inc. <http://www.zmanda.com/>
  28 #   Copyright (c) 2009,2010 Dustin J. Mitchell <dustin@zmanda.com>
  29 #
  30 #   Copying and distribution of this file, with or without modification, are
  31 #   permitted in any medium without royalty provided the copyright notice
  32 #   and this notice are preserved. This file is offered as-is, without any
  33 #   warranty.
  34
  35 #serial 9
  36
  37 AU_ALIAS([CHECK_SSL], [AX_CHECK_OPENSSL])
  38 AC_DEFUN([AX_CHECK_OPENSSL], [
  39     found=false
  40     AC_ARG_WITH([openssl],
  41         [AS_HELP_STRING([--with-openssl=DIR],
  42             [With openssl support, see http://www.openssl.org])],
  43         [
  44             case "$withval" in
  45             "" | y | ye | yes )
  46                 ssldirs="/usr/local/ssl /usr/lib/ssl /usr/ssl /usr/pkg /usr/local /usr"
  47               ;;
  48             n | no )
  49               ;;
  50             *) ssldirs="$withval"
  51               ;;
  52             esac
  53         ], [
  54             ssldirs="/usr/local/ssl /usr/lib/ssl /usr/ssl /usr/pkg /usr/local /usr"
  55         ])
  56
  57     AS_IF([test "${with_openssl}" != "no"], [
  58         OPENSSL_INCLUDES=
  59         for ssldir in $ssldirs; do
  60             AC_MSG_CHECKING([for openssl/ssl.h in $ssldir])
  61             AS_IF([ test -f "$ssldir/include/openssl/ssl.h" ], [
  62                 OPENSSL_INCLUDES="-I$ssldir/include"
  63                 OPENSSL_LDFLAGS="-L$ssldir/lib"
  64                 OPENSSL_LIBS="-lssl -lcrypto"
  65                 found=true
  66                 AC_MSG_RESULT([yes])
  67                 break
  68             ], [
  69                 AC_MSG_RESULT([no])
  70             ])
  71         done])
  72
  73     AS_IF([test "${with_openssl}" != "no" && test ! ${found}], [
  74         # if pkg-config is installed and openssl has installed a .pc file,
  75         # then use that information and don't search ssldirs
  76         AC_PATH_PROG([PKG_CONFIG], [pkg-config])
  77         if test x"$PKG_CONFIG" != x""; then
  78             OPENSSL_LDFLAGS=`$PKG_CONFIG openssl --libs-only-L 2>/dev/null`
  79             if test $? = 0; then
  80                 OPENSSL_LIBS=`$PKG_CONFIG openssl --libs-only-l 2>/dev/null`
  81                 OPENSSL_INCLUDES=`$PKG_CONFIG openssl --cflags-only-I 2>/dev/null`
  82                 found=true
  83             fi
  84         fi
  85     ])
  86
  87     AS_IF([test "${with_openssl}" != "no" && test ${found}], [
  88
  89         # try the preprocessor and linker with our new flags,
  90         # being careful not to pollute the global LIBS, LDFLAGS, and CPPFLAGS
  91
  92         AC_MSG_CHECKING([whether compiling and linking against OpenSSL works])
  93         echo "Trying link with OPENSSL_LDFLAGS=$OPENSSL_LDFLAGS;" \
  94             "OPENSSL_LIBS=$OPENSSL_LIBS; OPENSSL_INCLUDES=$OPENSSL_INCLUDES" >&AS_MESSAGE_LOG_FD
  95
  96         save_LIBS="$LIBS"
  97         save_LDFLAGS="$LDFLAGS"
  98         save_CPPFLAGS="$CPPFLAGS"
  99         LDFLAGS="$LDFLAGS $OPENSSL_LDFLAGS"
 100         LIBS="$OPENSSL_LIBS $LIBS"
 101         CPPFLAGS="$OPENSSL_INCLUDES $CPPFLAGS"
 102         AC_LINK_IFELSE(
 103             [AC_LANG_PROGRAM([#include <openssl/ssl.h>], [SSL_new(NULL)])],
 104             [
 105                 AC_MSG_RESULT([yes])
 106                 $1
 107             ], [
 108                 AC_MSG_RESULT([no])
 109                 $2
 110             ])
 111         CPPFLAGS="$save_CPPFLAGS"
 112         LDFLAGS="$save_LDFLAGS"
 113         LIBS="$save_LIBS"
 114
 115         AC_SUBST([OPENSSL_INCLUDES])
 116         AC_SUBST([OPENSSL_LIBS])
 117         AC_SUBST([OPENSSL_LDFLAGS])
 118     ], [ $2 ])
 119 ])