m4/ax_check_atm.m4

   1 # SYNOPSIS
   2 #
   3 #   AX_CHECK_ATM([action-if-found[, action-if-not-found]])
   4 #
   5 # DESCRIPTION
   6 #
   7 #   Look for libatm in a number of default locations, or in a provided location
   8 #   (via --with-atm=). Sets
   9 #       ATM_CFLAGS
  10 #       ATM_LDFLAGS
  11 #       ATM_LIBS
  12 #
  13 #   and calls ACTION-IF-FOUND or ACTION-IF-NOT-FOUND appropriately
  14 #
  15 # LICENSE
  16 #
  17 #   Copyright (c) 2021 Eivind Naess <eivnaes@yahoo.com>
  18 #
  19 #   Copying and distribution of this file, with or without modification, are
  20 #   permitted in any medium without royalty provided the copyright notice
  21 #   and this notice are preserved. This file is offered as-is, without any
  22 #   warranty.
  23
  24 #serial 1
  25
  26 AC_DEFUN([AX_CHECK_ATM], [
  27     AC_ARG_WITH([atm],
  28         [AS_HELP_STRING([--with-atm=DIR],
  29             [With libatm support, see http://linux-atm.sourceforge.net])],
  30         [
  31             case "$withval" in
  32             "" | y | ye | yes)
  33                 atmdirs="/usr/local /usr/lib /usr"
  34               ;;
  35             n | no)
  36                 with_atm="no"
  37               ;;
  38             *)
  39                 atmdirs="$withval"
  40               ;;
  41             esac
  42         ])
  43
  44     if [ test "x${with_atm}" != "xno" ] ; then
  45         ATM_LIBS="-latm"
  46         for atmdir in $atmdirs; do
  47             AC_MSG_CHECKING([for atm.h in $atmdir])
  48             if test -f "$atmdir/include/atm.h"; then
  49                 ATM_CFLAGS="-I$atmdir/include"
  50                 ATM_LDFLAGS="-L$atmdir/lib"
  51                 AC_MSG_RESULT([yes])
  52                 break
  53             else
  54                 AC_MSG_RESULT([no])
  55             fi
  56         done
  57
  58         # try the preprocessor and linker with our new flags,
  59         # being careful not to pollute the global LIBS, LDFLAGS, and CPPFLAGS
  60
  61         AC_MSG_CHECKING([if compiling and linking against libatm works])
  62
  63         save_LIBS="$LIBS"
  64         save_LDFLAGS="$LDFLAGS"
  65         save_CPPFLAGS="$CPPFLAGS"
  66         LDFLAGS="$LDFLAGS $ATM_LDFLAGS"
  67         LIBS="$ATM_LIBS $LIBS"
  68         CPPFLAGS="$ATM_CFLAGS $CPPFLAGS"
  69         AC_LINK_IFELSE(
  70             [AC_LANG_PROGRAM(
  71                 [#include <atm.h>
  72                  #include <stddef.h>],
  73                 [text2atm(NULL,NULL,0,0);])],
  74             [
  75                 AC_MSG_RESULT([yes])
  76                 with_atm=yes
  77                 $1
  78             ], [
  79                 AC_MSG_RESULT([no])
  80                 with_atm=""
  81                 $2
  82             ])
  83         CPPFLAGS="$save_CPPFLAGS"
  84         LDFLAGS="$save_LDFLAGS"
  85         LIBS="$save_LIBS"
  86
  87         AC_SUBST([ATM_CFLAGS])
  88         AC_SUBST([ATM_LIBS])
  89         AC_SUBST([ATM_LDFLAGS])
  90     fi
  91     AM_CONDITIONAL(WITH_LIBATM, test -n "${with_atm}")
  92 ])
  93