configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([ppp],
   3         [2.4.10-dev],
   4         [https://github.com/ppp-project/ppp])
   5
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AM_INIT_AUTOMAKE
  10 AM_MAINTAINER_MODE([enable])
  11
  12 AC_LANG(C)
  13 AC_CONFIG_SRCDIR([pppd/main.c])
  14 AC_CONFIG_HEADERS([pppd/config.h pppd/pppdconf.h])
  15
  16 # Checks for programs.
  17 AC_PROG_CC
  18 AM_PROG_CC_C_O
  19 AC_PROG_INSTALL
  20 AC_PROG_LIBTOOL
  21 AC_PROG_LN_S
  22
  23 PKG_PROG_PKG_CONFIG
  24
  25 AC_CANONICAL_HOST
  26 build_linux=no
  27 build_sunos=no
  28
  29 case "${host_os}" in
  30     linux*)
  31         build_linux=yes
  32         ;;
  33     solaris2*)
  34         build_sunos=yes
  35         ;;
  36     *)
  37         AC_MSG_ERROR(["OS ${host_os} not supported"])
  38         ;;
  39 esac
  40
  41 AM_CONDITIONAL([LINUX], [test "x${build_linux}" = "xyes" ])
  42 AM_CONDITIONAL([SUNOS], [test "x${build_sunos}" = "xyes" ])
  43 AM_COND_IF([SUNOS],
  44       CFLAGS="$CFLAGS -DSOL2 -DSRV4")
  45
  46 #
  47 # Checks for header files, these will set the HAVE_[FILE]_H macros in config.h
  48 AC_HEADER_STDBOOL
  49 AC_CHECK_HEADERS([  \
  50     asm/types.h     \
  51     crypt.h         \
  52     paths.h         \
  53     shadow.h        \
  54     sys/dlpi.h      \
  55     sys/ioctl.h     \
  56     sys/socket.h    \
  57     sys/time.h      \
  58     sys/uio.h       \
  59     time.h          \
  60     unistd.h        \
  61     utmp.h])
  62
  63 #
  64 # Check for linux specific headers, required by pppoe, or pppol2tp
  65 AM_COND_IF([LINUX], [
  66     AC_CHECK_HEADERS([          \
  67         net/bpf.h               \
  68         net/if.h                \
  69         net/if_types.h          \
  70         net/if_arp.h            \
  71         linux/if.h              \
  72         linux/if_ether.h        \
  73         linux/if_packet.h       \
  74         netinet/if_ether.h      \
  75         netpacket/packet.h])])
  76
  77 AC_CHECK_SIZEOF(unsigned int)
  78 AC_CHECK_SIZEOF(unsigned long)
  79 AC_CHECK_SIZEOF(unsigned short)
  80
  81 # Checks for library functions.
  82 AC_CHECK_FUNCS([    \
  83     mmap            \
  84     logwtmp         \
  85     strerror])
  86
  87 #
  88 # If libc doesn't provide logwtmp, check if libutil provides logwtmp(), and if so link to it.
  89 AS_IF([test "x${ac_cv_func_logwtmp}" != "xyes"], [
  90     AC_CHECK_LIB([util], [logwtmp], [
  91         AC_DEFINE(HAVE_LOGWTMP, 1, [System provides the logwtmp() function])
  92         AC_SUBST([UTIL_LIBS], ["-lutil"])
  93     ])
  94 ])
  95
  96 #
  97 # Check if libcrypt have crypt() function
  98 AC_CHECK_LIB([crypt], [crypt],
  99     AC_SUBST([CRYPT_LIBS], ["-lcrypt"]))
 100
 101 #
 102 # Should pppd link with -lsystemd (Linux only)
 103 AC_ARG_ENABLE([systemd],
 104     AS_HELP_STRING([--enable-systemd], [Enable support for systemd notification]))
 105 AM_CONDITIONAL(WITH_SYSTEMD, test "x${enable_systemd}" = "xyes")
 106 AM_COND_IF([WITH_SYSTEMD],
 107     AC_DEFINE([SYSTEMD], 1, [Enable support for systemd notifications]))
 108
 109 if test "x${enable_systemd}" = "xyes"; then
 110         PKG_CHECK_MODULES([systemd], [systemd])
 111 fi
 112
 113 #
 114 # Enable Callback Protocol Support, disabled by default
 115 AC_ARG_ENABLE([cbcp],
 116     AS_HELP_STRING([--enable-cbcp], [Enable Callback Protocol]))
 117 AM_CONDITIONAL(PPP_WITH_CBCP, test "x${enable_cbcp}" = "xyes")
 118 AM_COND_IF([PPP_WITH_CBCP],
 119     AC_DEFINE([PPP_WITH_CBCP], 1, [Have Callback Protocol support]))
 120
 121 #
 122 # Disable support for limiting session duration by maximum octets
 123 AC_ARG_ENABLE([maxoctets],
 124     AS_HELP_STRING([--disable-maxoctets], [Disable support for limiting session by maximum octets]))
 125 AS_IF([test "x$enable_maxoctets" != "xno"],
 126     AC_DEFINE([PPP_WITH_MAXOCTETS], 1, [Limit sessions by maximum number of octets]))
 127
 128 #
 129 # Disable Microsoft extensions will remove CHAP and MPPE support
 130 AC_ARG_ENABLE([microsoft-extensions],
 131     AS_HELP_STRING([--disable-microsoft-extensions], [Disable Microsoft CHAP / MPPE extensions]))
 132
 133 AM_CONDITIONAL(PPP_WITH_CHAPMS, test "x${enable_microsoft_extensions}" != "xno")
 134 AM_COND_IF([PPP_WITH_CHAPMS],
 135     AC_DEFINE([PPP_WITH_CHAPMS], 1, [Have Microsoft CHAP support]))
 136
 137 AM_CONDITIONAL(PPP_WITH_MPPE, test "x${enable_microsoft_extensions}" != "xno")
 138 AM_COND_IF([PPP_WITH_MPPE],
 139     AC_DEFINE([PPP_WITH_MPPE], 1, [Have Microsoft MPPE support]))
 140
 141 #
 142 # Enable Microsoft LAN Manager support, depends on Microsoft Extensions
 143 AC_ARG_ENABLE([mslanman],
 144     AS_HELP_STRING([--enable-mslanman], [Enable Microsoft LAN Manager support]))
 145 AS_IF([test "x${enable_mslanman}" = "xyes" && test "x${enable_microsoft_extensions}" != "xno"],
 146     AC_DEFINE([PPP_WITH_MSLANMAN], 1, [Have Microsoft LAN Manager support]))
 147
 148 #
 149 # Disable IPv6 support
 150 AC_ARG_ENABLE([ipv6cp],
 151     AS_HELP_STRING([--disable-ipv6cp], [Disable IPv6 Control Protocol]))
 152 AM_CONDITIONAL(PPP_WITH_IPV6CP, test "x${enable_ipv6cp}" != "xno")
 153 AM_COND_IF([PPP_WITH_IPV6CP],
 154     AC_DEFINE(PPP_WITH_IPV6CP, 1, [Have IPv6 Control Protocol]))
 155
 156 #
 157 # Disable Multilink support
 158 AC_ARG_ENABLE([multilink],
 159     AS_HELP_STRING([--enable-multilink], [Enable multilink support]))
 160 AM_CONDITIONAL(PPP_WITH_MULTILINK, test "x${enable_multilink}" = "xyes")
 161 AM_COND_IF([PPP_WITH_MULTILINK],
 162     AC_DEFINE([PPP_WITH_MULTILINK], 1, [Have multilink support]))
 163 AS_IF([test "x${build_sunos}" = "xyes" && test "x${enable_multilink}" = "xyes"],
 164     [AC_MSG_ERROR([Multilink is not supported on SunOS])])
 165
 166 #
 167 # Multilink require Trivial Database Support
 168 AM_CONDITIONAL(PPP_WITH_TDB, test "x${enable_multilink}" = "xyes")
 169 AM_COND_IF([PPP_WITH_TDB],
 170     AC_DEFINE([PPP_WITH_TDB], 1, [Include TDB support]))
 171
 172 #
 173 # Enable support for loadable plugins
 174 AC_ARG_ENABLE([plugins],
 175     AS_HELP_STRING([--disable-plugins], [Disable support for loadable plugins]))
 176 AS_IF([test "x$enable_plugins" != "xno"],
 177     AC_DEFINE([PPP_WITH_PLUGINS], 1, [Have support for loadable plugins]))
 178 AM_CONDITIONAL(PPP_WITH_PLUGINS, test "x${enable_plugins}" != "xno")
 179
 180 #
 181 # Disable EAP-TLS support
 182 AC_ARG_ENABLE([eaptls],
 183     AS_HELP_STRING([--disable-eaptls], [Disable EAP-TLS authentication support]))
 184 AS_IF([test "x$enable_eaptls" != "xno"],
 185     AC_DEFINE([PPP_WITH_EAPTLS], 1, [Have EAP-TLS authentication support]))
 186 AM_CONDITIONAL(PPP_WITH_EAPTLS, test "x${enable_eaptls}" != "xno")
 187
 188 #
 189 # Disable PEAP support
 190 AC_ARG_ENABLE([peap],
 191     AS_HELP_STRING([--disable-peap], [Disable PEAP authentication support]))
 192 AS_IF([test "x${enable_peap}" != "xno"],
 193     AC_DEFINE([PPP_WITH_PEAP], 1, [Have PEAP authentication support]))
 194 AM_CONDITIONAL([PPP_WITH_PEAP], test "x${enable_peap}" != "xno")
 195
 196 #
 197 # Disable OpenSSL engine support
 198 AC_ARG_ENABLE([openssl-engine],
 199     AS_HELP_STRING([--disable-openssl-engine], [Disable OpenSSL engine support]))
 200 AS_IF([test "x$enable_openssl_engine" != "xno"], [],
 201     AC_DEFINE([OPENSSL_NO_ENGINE], 1, [OpenSSL engine support]))
 202
 203 #
 204 # Specify runtime directory
 205 AC_ARG_WITH([plugin-dir],
 206         AC_HELP_STRING([--with-plugin-dir=DIR], [Specify the plugin directory for pppd]))
 207 AS_IF([test -n "$with_plugin_dir"],
 208         [PPPD_PLUGIN_DIR="$with_plugin_dir"],
 209         [PPPD_PLUGIN_DIR="${libdir}/pppd/$VERSION"])
 210 AC_SUBST(PPPD_PLUGIN_DIR, "$PPPD_PLUGIN_DIR", [The pppd plugin directory])
 211
 212 #
 213 # Specify runtime directory
 214 AC_ARG_WITH([runtime-dir],
 215         AC_HELP_STRING([--with-runtime-dir=DIR], [Specify the runtime directory for pppd]))
 216 AS_IF([test -n "$with_runtime_dir"],
 217         [PPPD_RUNTIME_DIR="$with_runtime_dir"],
 218         [PPPD_RUNTIME_DIR="${localstatedir}/run/pppd"])
 219 AC_SUBST(PPPD_RUNTIME_DIR)
 220
 221 #
 222 # Specify runtime directory
 223 AC_ARG_WITH([logfile-dir],
 224         AC_HELP_STRING([--with-logfile-dir=DIR], [Specify the log directory for pppd]))
 225 AS_IF([test -n "$with_logfile_dir"],
 226         [PPPD_LOGFILE_DIR="$with_logfile_dir"],
 227         [PPPD_LOGFILE_DIR="${localstatedir}/log/pppd"])
 228 AC_SUBST(PPPD_LOGFILE_DIR)
 229
 230 #
 231 # Check for OpenSSL
 232 AX_CHECK_OPENSSL
 233 AM_CONDITIONAL(WITH_OPENSSL, test "x${with_openssl}" != "xno")
 234
 235 #
 236 # Check if OpenSSL has compiled in support for various ciphers
 237 AS_IF([test "x${with_openssl}" != "xno" ], [
 238     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_MD4], [md4])
 239     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_MD5], [md5])
 240     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_DES], [des])
 241     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_SHA], [sha])
 242 ], [
 243     AS_IF([test "x${enable_eaptls}" != "xno" || test "x${enable_peap}" != "xno"],
 244         [AC_MSG_ERROR([OpenSSL not found, and if this is your intention then run configure --disable-eaptls and --disable-peap])])
 245 ])
 246
 247 AM_CONDITIONAL([OPENSSL_HAVE_MD4], test "x${ac_cv_openssl_md4}" = "xyes")
 248 AM_COND_IF([OPENSSL_HAVE_MD4],,
 249     AC_DEFINE([USE_MD4], 1, [Use MD4 included with pppd]))
 250
 251 AM_CONDITIONAL([OPENSSL_HAVE_MD5], test "x${ac_cv_openssl_md5}" = "xyes")
 252 AM_COND_IF([OPENSSL_HAVE_MD5],,
 253     AC_DEFINE([USE_MD5], 1, [Use MD5 included with pppd]))
 254
 255 AM_CONDITIONAL([OPENSSL_HAVE_SHA], test "x${ac_cv_openssl_sha}" = "xyes")
 256 AM_COND_IF([OPENSSL_HAVE_SHA],,
 257     AC_DEFINE([USE_SHA], 1, [Use SHA included with pppd]))
 258
 259 AM_CONDITIONAL([OPENSSL_HAVE_DES], test "x${ac_cv_openssl_des}" = "xyes")
 260 AM_COND_IF([OPENSSL_HAVE_DES],,
 261     AC_DEFINE([USE_CRYPT], 1, [Use DES included with pppd]))
 262
 263 #
 264 # If OpenSSL doesn't support DES, then use the one from libcrypt (glibc dropped support for this in 2.27).
 265 AS_IF([test "x${ac_cv_openssl_des}" = "xno" ], [
 266     AC_CHECK_LIB([crypt], [encrypt],
 267         [LIBS="$LIBS -lcrypt"],
 268         [AC_MSG_ERROR([OpenSSL not found or does not support DES, and libcrypt also doesn't support encrypt])]
 269     )
 270 ])
 271
 272 #
 273 # With libsrp support
 274 AX_CHECK_SRP([
 275     AC_DEFINE([PPP_WITH_SRP], 1, [Support for libsrp authentication module])])
 276
 277 #
 278 # With libatm support
 279 AX_CHECK_ATM
 280
 281 #
 282 # With libpam support
 283 AX_CHECK_PAM(AC_DEFINE([PPP_WITH_PAM], 1, [Support for Pluggable Authentication Modules]))
 284 AM_CONDITIONAL(PPP_WITH_PAM, test "x${with_pam}" = "xyes")
 285
 286 #
 287 # With libpcap support, activate pppd on network activity
 288 AX_CHECK_PCAP
 289
 290 #
 291 # SunOS provides a version of libpcap that would work, but SunOS has no support for activity filter
 292 AM_CONDITIONAL([PPP_WITH_FILTER], [ test "x${with_pcap}" = "xyes" && test "x${build_sunos}" != "xyes" ])
 293 AM_COND_IF([PPP_WITH_FILTER], [
 294     AC_DEFINE([PPP_WITH_FILTER], 1, [Have packet activity filter support])], [
 295     AS_IF([test "x${build_sunos}" = "xyes"], [
 296         AC_MSG_WARN([Packet activity filter not supported on SunOS])
 297         with_pcap="no"
 298         ])
 299     ])
 300
 301 #
 302 # Some contributions require GTK/GLIB
 303 AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk], [Build contributions with the GTK+ interface]))
 304 if test "x${with_gtk}" = "xyes"; then
 305     PKG_CHECK_MODULES([GTK], [gtk+-2.0])
 306     PKG_CHECK_MODULES([GLIB], [glib-2.0])
 307 fi
 308 AM_CONDITIONAL([WITH_GTK], test "x${with_gtk}" = "xyes")
 309
 310
 311 AC_CONFIG_FILES([
 312     Makefile
 313     chat/Makefile
 314     contrib/Makefile
 315     contrib/pppgetpass/Makefile
 316     common/Makefile
 317     include/Makefile
 318     modules/Makefile
 319     pppd/Makefile
 320     pppd/pppd.pc
 321     pppd/plugins/Makefile
 322     pppd/plugins/pppoe/Makefile
 323     pppd/plugins/pppoatm/Makefile
 324     pppd/plugins/pppol2tp/Makefile
 325     pppd/plugins/radius/Makefile
 326     pppdump/Makefile
 327     pppstats/Makefile
 328     scripts/Makefile
 329     ])
 330 AC_OUTPUT
 331
 332
 333 AS_IF([test "x${build_sunos}" = "xyes" ], [[
 334     echo "
 335 Setting up SunOS kernel module(s)"
 336     mkmkf() {
 337         rm -f $2
 338         if [ -f $1 ]; then
 339             echo "  $2 <= $1"
 340             sed -e "s,@DESTDIR@,$prefix,g" \
 341                 -e "s,@SYSCONF@,$sysconfdir,g" \
 342                 -e "s,@CC@,$CC,g" \
 343                 -e "s|@CFLAGS@|$CFLAGS|g" $1 > $2
 344         fi
 345     }
 346
 347     release=`uname -r`
 348     karch=`/usr/bin/isainfo -k`
 349     makext="sol2"
 350     archvariant=
 351
 352     case "$karch" in
 353         amd64)
 354             archvariant='-64x'
 355             ;;
 356         sparcv9)
 357             archvariant='-64'
 358             ;;
 359         *)
 360             ;;
 361     esac
 362
 363     usegcc=$CC
 364     if [ -x /opt/SUNWspro/bin/cc -a "$usegcc" != gcc ] &&
 365        /opt/SUNWspro/bin/cc -flags >/dev/null 2>&1; then
 366       if [ "$archvariant" = "-64x" ]; then
 367         ( cd /tmp; echo "int x;" > ppp$$.c
 368           /opt/SUNWspro/bin/cc -c -errwarn -xchip=opteron -m64 ppp$$.c >/dev/null 2>&1 || (
 369             echo "WorkShop C is unable to make 64 bit modules, and your $karch system needs"
 370             echo "them.  Consider upgrading cc on this machine."
 371             rm -f ppp$$.c
 372             exit 1
 373           ) || exit 1
 374           rm -f ppp$$.c ppp$$.o
 375         ) || exit 1
 376       fi
 377     elif gcc --version >/dev/null 2>&1; then
 378       archvariant=gcc$archvariant
 379       compiletype=.gcc
 380       if [ "$archvariant" = "gcc-64" -o"$archvariant" = "gcc-64x" ]; then
 381         ( cd /tmp; touch ppp$$.c
 382           gcc -c -m64 ppp$$.c >/dev/null 2>&1 || (
 383             echo "gcc is unable to make 64 bit modules, and your $karch system needs them."
 384             echo "Consider upgrading gcc on this machine, or switching to Sun WorkShop."
 385             rm -f ppp$$.c
 386             exit 1
 387           ) || exit 1
 388           rm -f ppp$$.c ppp$$.o
 389         ) || exit 1
 390       fi
 391     else
 392       echo "C compiler not found; hoping for the best."
 393     fi
 394
 395     mkmkf solaris/Makedefs$compiletype Makedefs.com
 396     mkmkf solaris/Makefile.sol2$archvariant solaris/Makefile
 397 ]])
 398
 399 echo "
 400 $PACKAGE_NAME version $PACKAGE_VERSION
 401     Prefix...............: $prefix
 402     Runtime Dir..........: $PPPD_RUNTIME_DIR
 403     Logfile Dir..........: $PPPD_LOGFILE_DIR
 404     Plugin Dir...........: $PPPD_PLUGIN_DIR
 405     With OpenSSL.........: ${with_openssl:-yes}
 406     With libatm..........: ${with_atm:-no}
 407     With libpam..........: ${with_pam:-no}
 408     With libpcap.........: ${with_pcap:-no}
 409     With libsrp..........: ${with_srp:-no}
 410     C Compiler...........: $CC $CFLAGS
 411     Linker...............: $LD $LDFLAGS $LIBS
 412
 413 Features enabled
 414     Microsoft Extensions.: ${enable_microsoft_extensions:-yes}
 415     Multilink............: ${enable_multilink:-no}
 416     Plugins..............: ${enable_plugins:-yes}
 417     CBCP.................: ${enable_cbcp:-no}
 418     IPV6CP...............: ${enable_ipv6cp:-yes}
 419     EAP-TLS..............: ${enable_eaptls:-yes}
 420     PEAP.................: ${enable_peap:-yes}
 421     systemd notifications: ${enable_systemd:-no}
 422 "