configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([ppp],
   3         [2.5.0],
   4         [https://github.com/ppp-project/ppp])
   5
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AM_INIT_AUTOMAKE
  10 AM_MAINTAINER_MODE([enable])
  11
  12 AC_LANG(C)
  13 AC_CONFIG_SRCDIR([pppd/main.c])
  14 AC_CONFIG_HEADERS([pppd/config.h pppd/pppdconf.h pppd/plugins/pppoe/config.h])
  15 AC_ENABLE_STATIC(no)
  16
  17 # Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22 LT_INIT
  23
  24 PKG_PROG_PKG_CONFIG
  25
  26 AC_CANONICAL_HOST
  27 build_linux=no
  28 build_sunos=no
  29
  30 case "${host_os}" in
  31     linux*)
  32         build_linux=yes
  33         ;;
  34     solaris2*)
  35         build_sunos=yes
  36         ;;
  37     *)
  38         AC_MSG_ERROR(["OS ${host_os} not supported"])
  39         ;;
  40 esac
  41
  42 AM_CONDITIONAL([LINUX], [test "x${build_linux}" = "xyes" ])
  43 AM_CONDITIONAL([SUNOS], [test "x${build_sunos}" = "xyes" ])
  44 AM_COND_IF([SUNOS],
  45       CFLAGS="$CFLAGS -DSOL2 -DSRV4")
  46
  47 #
  48 # Checks for header files, these will set the HAVE_[FILE]_H macros in config.h
  49 AC_HEADER_STDBOOL
  50 AC_CHECK_HEADERS([  \
  51     asm/types.h     \
  52     crypt.h         \
  53     paths.h         \
  54     shadow.h        \
  55     stddef.h        \
  56     stdarg.h        \
  57     sys/dlpi.h      \
  58     sys/ioctl.h     \
  59     sys/socket.h    \
  60     sys/time.h      \
  61     sys/uio.h       \
  62     time.h          \
  63     unistd.h        \
  64     utmp.h])
  65
  66 #
  67 # Check for linux specific headers, required by pppoe, or pppol2tp
  68 AM_COND_IF([LINUX], [
  69     AC_CHECK_HEADERS([          \
  70         net/bpf.h               \
  71         net/if.h                \
  72         net/if_types.h          \
  73         net/if_arp.h            \
  74         linux/if.h              \
  75         linux/if_ether.h        \
  76         linux/if_packet.h       \
  77         netinet/if_ether.h      \
  78         netpacket/packet.h])])
  79
  80 AC_CHECK_SIZEOF(unsigned int)
  81 AC_CHECK_SIZEOF(unsigned long)
  82 AC_CHECK_SIZEOF(unsigned short)
  83
  84 # Checks for library functions.
  85 AC_CHECK_FUNCS([    \
  86     mmap            \
  87     logwtmp         \
  88     strerror])
  89
  90 #
  91 # If libc doesn't provide logwtmp, check if libutil provides logwtmp(), and if so link to it.
  92 AS_IF([test "x${ac_cv_func_logwtmp}" != "xyes"], [
  93     AC_CHECK_LIB([util], [logwtmp], [
  94         AC_DEFINE(HAVE_LOGWTMP, 1, [System provides the logwtmp() function])
  95         AC_SUBST([UTIL_LIBS], ["-lutil"])
  96     ])
  97 ])
  98
  99 #
 100 # Check if libcrypt have crypt() function
 101 AC_CHECK_LIB([crypt], [crypt],
 102     AC_SUBST([CRYPT_LIBS], ["-lcrypt"]))
 103
 104 #
 105 # Should pppd link with -lsystemd (Linux only)
 106 AC_ARG_ENABLE([systemd],
 107     AS_HELP_STRING([--enable-systemd], [Enable support for systemd notification]))
 108 AM_CONDITIONAL(WITH_SYSTEMD, test "x${enable_systemd}" = "xyes")
 109 AM_COND_IF([WITH_SYSTEMD],
 110     AC_DEFINE([SYSTEMD], 1, [Enable support for systemd notifications]))
 111 AS_IF([test "x${enable_systemd}" = "xyes"], [
 112         PKG_CHECK_MODULES([SYSTEMD], [libsystemd])])
 113
 114 #
 115 # Enable Callback Protocol Support, disabled by default
 116 AC_ARG_ENABLE([cbcp],
 117     AS_HELP_STRING([--enable-cbcp], [Enable Callback Protocol]))
 118 AM_CONDITIONAL(PPP_WITH_CBCP, test "x${enable_cbcp}" = "xyes")
 119 AM_COND_IF([PPP_WITH_CBCP],
 120     AC_DEFINE([PPP_WITH_CBCP], 1, [Have Callback Protocol support]))
 121
 122 #
 123 # Disable Microsoft extensions will remove CHAP and MPPE support
 124 AC_ARG_ENABLE([microsoft-extensions],
 125     AS_HELP_STRING([--disable-microsoft-extensions], [Disable Microsoft CHAP / MPPE extensions]))
 126
 127 AM_CONDITIONAL(PPP_WITH_CHAPMS, test "x${enable_microsoft_extensions}" != "xno")
 128 AM_COND_IF([PPP_WITH_CHAPMS],
 129     AC_DEFINE([PPP_WITH_CHAPMS], 1, [Have Microsoft CHAP support]))
 130
 131 AM_CONDITIONAL(PPP_WITH_MPPE, test "x${enable_microsoft_extensions}" != "xno")
 132 AM_COND_IF([PPP_WITH_MPPE],
 133     AC_DEFINE([PPP_WITH_MPPE], 1, [Have Microsoft MPPE support]))
 134
 135 #
 136 # Enable Microsoft LAN Manager support, depends on Microsoft Extensions
 137 AC_ARG_ENABLE([mslanman],
 138     AS_HELP_STRING([--enable-mslanman], [Enable Microsoft LAN Manager support]))
 139 AS_IF([test "x${enable_mslanman}" = "xyes" && test "x${enable_microsoft_extensions}" != "xno"],
 140     AC_DEFINE([PPP_WITH_MSLANMAN], 1, [Have Microsoft LAN Manager support]))
 141
 142 #
 143 # Disable IPv6 support
 144 AC_ARG_ENABLE([ipv6cp],
 145     AS_HELP_STRING([--disable-ipv6cp], [Disable IPv6 Control Protocol]))
 146 AM_CONDITIONAL(PPP_WITH_IPV6CP, test "x${enable_ipv6cp}" != "xno")
 147 AM_COND_IF([PPP_WITH_IPV6CP],
 148     AC_DEFINE(PPP_WITH_IPV6CP, 1, [Have IPv6 Control Protocol]))
 149
 150 #
 151 # Disable Multilink support
 152 AC_ARG_ENABLE([multilink],
 153     AS_HELP_STRING([--enable-multilink], [Enable multilink support]))
 154 AM_CONDITIONAL(PPP_WITH_MULTILINK, test "x${enable_multilink}" = "xyes")
 155 AM_COND_IF([PPP_WITH_MULTILINK],
 156     AC_DEFINE([PPP_WITH_MULTILINK], 1, [Have multilink support]))
 157 AS_IF([test "x${build_sunos}" = "xyes" && test "x${enable_multilink}" = "xyes"],
 158     [AC_MSG_ERROR([Multilink is not supported on SunOS])])
 159
 160 #
 161 # Multilink require Trivial Database Support
 162 AM_CONDITIONAL(PPP_WITH_TDB, test "x${enable_multilink}" = "xyes")
 163 AM_COND_IF([PPP_WITH_TDB],
 164     AC_DEFINE([PPP_WITH_TDB], 1, [Include TDB support]))
 165
 166 #
 167 # Enable support for loadable plugins
 168 AC_ARG_ENABLE([plugins],
 169     AS_HELP_STRING([--disable-plugins], [Disable support for loadable plugins]))
 170 AS_IF([test "x$enable_plugins" != "xno"],
 171     AC_DEFINE([PPP_WITH_PLUGINS], 1, [Have support for loadable plugins]))
 172 AM_CONDITIONAL(PPP_WITH_PLUGINS, test "x${enable_plugins}" != "xno")
 173
 174 #
 175 # Disable EAP-TLS support
 176 AC_ARG_ENABLE([eaptls],
 177     AS_HELP_STRING([--disable-eaptls], [Disable EAP-TLS authentication support]))
 178 AS_IF([test "x$enable_eaptls" != "xno"],
 179     AC_DEFINE([PPP_WITH_EAPTLS], 1, [Have EAP-TLS authentication support]))
 180 AM_CONDITIONAL(PPP_WITH_EAPTLS, test "x${enable_eaptls}" != "xno")
 181
 182 #
 183 # Disable PEAP support
 184 AC_ARG_ENABLE([peap],
 185     AS_HELP_STRING([--disable-peap], [Disable PEAP authentication support]))
 186 AS_IF([test "x${enable_peap}" != "xno"],
 187     AC_DEFINE([PPP_WITH_PEAP], 1, [Have PEAP authentication support]))
 188 AM_CONDITIONAL([PPP_WITH_PEAP], test "x${enable_peap}" != "xno")
 189
 190 #
 191 # Disable OpenSSL engine support
 192 AC_ARG_ENABLE([openssl-engine],
 193     AS_HELP_STRING([--disable-openssl-engine], [Disable OpenSSL engine support]))
 194 AS_IF([test "x$enable_openssl_engine" != "xno"], [],
 195     AC_DEFINE([OPENSSL_NO_ENGINE], 1, [OpenSSL engine support]))
 196
 197 #
 198 # Specify runtime directory
 199 AC_ARG_WITH([plugin-dir],
 200         AS_HELP_STRING([--with-plugin-dir=DIR],[Specify the plugin directory for pppd]))
 201 AS_IF([test -n "$with_plugin_dir"],
 202         [PPPD_PLUGIN_DIR="$with_plugin_dir"],
 203         [PPPD_PLUGIN_DIR="${libdir}/pppd/$VERSION"])
 204 AC_SUBST(PPPD_PLUGIN_DIR, "$PPPD_PLUGIN_DIR", [The pppd plugin directory])
 205
 206 #
 207 # Specify runtime directory
 208 AC_ARG_WITH([runtime-dir],
 209         AS_HELP_STRING([--with-runtime-dir=DIR],[Specify the runtime directory for pppd]))
 210 AS_IF([test -n "$with_runtime_dir"],
 211         [PPPD_RUNTIME_DIR="$with_runtime_dir"],
 212         [PPPD_RUNTIME_DIR="${runstatedir}/pppd"])
 213 AC_SUBST(PPPD_RUNTIME_DIR)
 214
 215 #
 216 # Specify runtime directory
 217 AC_ARG_WITH([logfile-dir],
 218         AS_HELP_STRING([--with-logfile-dir=DIR],[Specify the log directory for pppd]))
 219 AS_IF([test -n "$with_logfile_dir"],
 220         [PPPD_LOGFILE_DIR="$with_logfile_dir"],
 221         [PPPD_LOGFILE_DIR="${localstatedir}/log/ppp"])
 222 AC_SUBST(PPPD_LOGFILE_DIR)
 223
 224 #
 225 # Check for OpenSSL
 226 AX_CHECK_OPENSSL
 227 AM_CONDITIONAL(PPP_WITH_OPENSSL, test "x${with_openssl}" != "xno")
 228 AM_COND_IF([PPP_WITH_OPENSSL],
 229     AC_DEFINE([PPP_WITH_OPENSSL], 1, [PPP is compiled with openssl support]))
 230
 231 #
 232 # Check if OpenSSL has compiled in support for various ciphers
 233 AS_IF([test "x${with_openssl}" != "xno" ], [
 234     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_MD4], [md4])
 235     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_MD5], [md5])
 236     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_DES], [des])
 237     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_SHA], [sha])
 238 ], [
 239     AS_IF([test "x${enable_eaptls}" != "xno" || test "x${enable_peap}" != "xno"],
 240         [AC_MSG_ERROR([OpenSSL not found, and if this is your intention then run configure --disable-eaptls and --disable-peap])])
 241 ])
 242
 243 AM_CONDITIONAL([OPENSSL_HAVE_MD4], test "x${ac_cv_openssl_md4}" = "xyes")
 244 AM_COND_IF([OPENSSL_HAVE_MD4],
 245     AC_DEFINE([OPENSSL_HAVE_MD4], 1, [Use MD4 included with openssl]))
 246
 247 AM_CONDITIONAL([OPENSSL_HAVE_MD5], test "x${ac_cv_openssl_md5}" = "xyes")
 248 AM_COND_IF([OPENSSL_HAVE_MD5],
 249     AC_DEFINE([OPENSSL_HAVE_MD5], 1, [Use MD5 included with openssl]))
 250
 251 AM_CONDITIONAL([OPENSSL_HAVE_SHA], test "x${ac_cv_openssl_sha}" = "xyes")
 252 AM_COND_IF([OPENSSL_HAVE_SHA],
 253     AC_DEFINE([OPENSSL_HAVE_SHA], 1, [Use SHA included with openssl]))
 254
 255 AM_CONDITIONAL([OPENSSL_HAVE_DES], test "x${ac_cv_openssl_des}" = "xyes")
 256 AM_COND_IF([OPENSSL_HAVE_DES],
 257     AC_DEFINE([OPENSSL_HAVE_DES], 1, [Use DES included with openssl]))
 258
 259 #
 260 # With libsrp support
 261 AX_CHECK_SRP([
 262     AC_DEFINE([PPP_WITH_SRP], 1, [Support for libsrp authentication module])])
 263
 264 #
 265 # With libatm support
 266 AX_CHECK_ATM
 267
 268 #
 269 # With libpam support
 270 AX_CHECK_PAM(AC_DEFINE([PPP_WITH_PAM], 1, [Support for Pluggable Authentication Modules]))
 271 AM_CONDITIONAL(PPP_WITH_PAM, test "x${with_pam}" = "xyes")
 272
 273 #
 274 # With libpcap support, activate pppd on network activity
 275 AX_CHECK_PCAP
 276
 277 #
 278 # SunOS provides a version of libpcap that would work, but SunOS has no support for activity filter
 279 AM_CONDITIONAL([PPP_WITH_FILTER], [ test "x${with_pcap}" = "xyes" && test "x${build_sunos}" != "xyes" ])
 280 AM_COND_IF([PPP_WITH_FILTER], [
 281     AC_DEFINE([PPP_WITH_FILTER], 1, [Have packet activity filter support])], [
 282     AS_IF([test "x${build_sunos}" = "xyes"], [
 283         AC_MSG_WARN([Packet activity filter not supported on SunOS])
 284         with_pcap="no"
 285         ])
 286     ])
 287
 288 #
 289 # Some contributions require GTK/GLIB
 290 AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk], [Build contributions with the GTK+ interface]))
 291 if test "x${with_gtk}" = "xyes"; then
 292     PKG_CHECK_MODULES([GTK], [gtk+-2.0])
 293     PKG_CHECK_MODULES([GLIB], [glib-2.0])
 294 fi
 295 AM_CONDITIONAL([WITH_GTK], test "x${with_gtk}" = "xyes")
 296
 297 AC_DEFINE_UNQUOTED(PPPD_VERSION, "$VERSION", [Version of pppd])
 298
 299 AC_CONFIG_FILES([
 300     Makefile
 301     chat/Makefile
 302     contrib/Makefile
 303     contrib/pppgetpass/Makefile
 304     common/Makefile
 305     include/Makefile
 306     modules/Makefile
 307     pppd/Makefile
 308     pppd/pppd.pc
 309     pppd/plugins/Makefile
 310     pppd/plugins/pppoe/Makefile
 311     pppd/plugins/pppoatm/Makefile
 312     pppd/plugins/pppol2tp/Makefile
 313     pppd/plugins/radius/Makefile
 314     pppdump/Makefile
 315     pppstats/Makefile
 316     scripts/Makefile
 317     ])
 318 AC_OUTPUT
 319
 320
 321 AS_IF([test "x${build_sunos}" = "xyes" ], [[
 322     echo "
 323 Setting up SunOS kernel module(s)"
 324     mkmkf() {
 325         rm -f $2
 326         if [ -f $1 ]; then
 327             echo "  $2 <= $1"
 328             sed -e "s,@DESTDIR@,$prefix,g" \
 329                 -e "s,@SYSCONF@,$sysconfdir,g" \
 330                 -e "s,@CC@,$CC,g" \
 331                 -e "s|@CFLAGS@|$CFLAGS|g" $1 > $2
 332         fi
 333     }
 334
 335     release=`uname -r`
 336     karch=`/usr/bin/isainfo -k`
 337     makext="sol2"
 338     archvariant=
 339
 340     case "$karch" in
 341         amd64)
 342             archvariant='-64x'
 343             ;;
 344         sparcv9)
 345             archvariant='-64'
 346             ;;
 347         *)
 348             ;;
 349     esac
 350
 351     usegcc=$CC
 352     if [ -x /opt/SUNWspro/bin/cc -a "$usegcc" != gcc ] &&
 353        /opt/SUNWspro/bin/cc -flags >/dev/null 2>&1; then
 354       if [ "$archvariant" = "-64x" ]; then
 355         ( cd /tmp; echo "int x;" > ppp$$.c
 356           /opt/SUNWspro/bin/cc -c -errwarn -xchip=opteron -m64 ppp$$.c >/dev/null 2>&1 || (
 357             echo "WorkShop C is unable to make 64 bit modules, and your $karch system needs"
 358             echo "them.  Consider upgrading cc on this machine."
 359             rm -f ppp$$.c
 360             exit 1
 361           ) || exit 1
 362           rm -f ppp$$.c ppp$$.o
 363         ) || exit 1
 364       fi
 365     elif gcc --version >/dev/null 2>&1; then
 366       archvariant=gcc$archvariant
 367       compiletype=.gcc
 368       if [ "$archvariant" = "gcc-64" -o"$archvariant" = "gcc-64x" ]; then
 369         ( cd /tmp; touch ppp$$.c
 370           gcc -c -m64 ppp$$.c >/dev/null 2>&1 || (
 371             echo "gcc is unable to make 64 bit modules, and your $karch system needs them."
 372             echo "Consider upgrading gcc on this machine, or switching to Sun WorkShop."
 373             rm -f ppp$$.c
 374             exit 1
 375           ) || exit 1
 376           rm -f ppp$$.c ppp$$.o
 377         ) || exit 1
 378       fi
 379     else
 380       echo "C compiler not found; hoping for the best."
 381     fi
 382
 383     mkmkf solaris/Makedefs$compiletype Makedefs.com
 384     mkmkf solaris/Makefile.sol2$archvariant solaris/Makefile
 385 ]])
 386
 387 echo "
 388 $PACKAGE_NAME version $PACKAGE_VERSION
 389     Prefix...............: $prefix
 390     Runtime Dir..........: $PPPD_RUNTIME_DIR
 391     Logfile Dir..........: $PPPD_LOGFILE_DIR
 392     Plugin Dir...........: $PPPD_PLUGIN_DIR
 393     With OpenSSL.........: ${with_openssl:-yes}
 394     With libatm..........: ${with_atm:-no}
 395     With libpam..........: ${with_pam:-no}
 396     With libpcap.........: ${with_pcap:-no}
 397     With libsrp..........: ${with_srp:-no}
 398     C Compiler...........: $CC $CFLAGS
 399     Linker...............: $LD $LDFLAGS $LIBS
 400
 401 Features enabled
 402     Microsoft Extensions.: ${enable_microsoft_extensions:-yes}
 403     Multilink............: ${enable_multilink:-no}
 404     Plugins..............: ${enable_plugins:-yes}
 405     CBCP.................: ${enable_cbcp:-no}
 406     IPV6CP...............: ${enable_ipv6cp:-yes}
 407     EAP-TLS..............: ${enable_eaptls:-yes}
 408     PEAP.................: ${enable_peap:-yes}
 409     systemd notifications: ${enable_systemd:-no}
 410 "