configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([ppp],
   3         [2.4.10-dev],
   4         [https://github.com/ppp-project/ppp])
   5
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AM_INIT_AUTOMAKE
  10 AM_MAINTAINER_MODE([enable])
  11
  12 AC_LANG(C)
  13 AC_CONFIG_SRCDIR([pppd/main.c])
  14 AC_CONFIG_HEADERS([pppd/config.h pppd/pppdconf.h])
  15
  16 # Checks for programs.
  17 AC_PROG_CC
  18 AM_PROG_CC_C_O
  19 AC_PROG_INSTALL
  20 AC_PROG_LIBTOOL
  21 AC_PROG_LN_S
  22
  23 PKG_PROG_PKG_CONFIG
  24
  25 AC_CANONICAL_HOST
  26 build_linux=no
  27 build_sunos=no
  28
  29 case "${host_os}" in
  30     linux*)
  31         build_linux=yes
  32         ;;
  33     solaris2*)
  34         build_sunos=yes
  35         ;;
  36     *)
  37         AC_MSG_ERROR(["OS ${host_os} not supported"])
  38         ;;
  39 esac
  40
  41 AM_CONDITIONAL([LINUX], [test "${build_linux}" = "yes" ])
  42 AM_CONDITIONAL([SUNOS], [test "${build_sunos}" = "yes" ])
  43 AM_COND_IF([SUNOS],
  44       CFLAGS="$CFLAGS -DSOL2 -DSRV4")
  45
  46 #
  47 # Checks for header files, these will set the HAVE_[FILE]_H macros in config.h
  48 AC_HEADER_STDBOOL
  49 AC_CHECK_HEADERS([  \
  50     asm/types.h     \
  51     crypt.h         \
  52     paths.h         \
  53     shadow.h        \
  54     sys/dlpi.h      \
  55     sys/ioctl.h     \
  56     sys/socket.h    \
  57     sys/time.h      \
  58     sys/uio.h       \
  59     time.h          \
  60     unistd.h        \
  61     utmp.h])
  62
  63 #
  64 # Check for linux specific headers, required by pppoe, or pppol2tp
  65 AM_COND_IF([LINUX], [
  66     AC_CHECK_HEADERS([          \
  67         net/bpf.h               \
  68         net/if.h                \
  69         net/if_types.h          \
  70         net/if_arp.h            \
  71         linux/if.h              \
  72         linux/if_ether.h        \
  73         linux/if_packet.h       \
  74         netinet/if_ether.h      \
  75         netpacket/packet.h])])
  76
  77 AC_CHECK_SIZEOF(unsigned int)
  78 AC_CHECK_SIZEOF(unsigned long)
  79 AC_CHECK_SIZEOF(unsigned short)
  80
  81 # Checks for library functions.
  82 AC_CHECK_FUNCS([    \
  83     mmap            \
  84     logwtmp         \
  85     strerror])
  86
  87 #
  88 # If libc doesn't provide logwtmp, check if libutil provides logwtmp(), and if so link to it.
  89 AS_IF([test "x${ac_cv_func_logwtmp}" != "xyes"], [
  90     AC_CHECK_LIB([util], [logwtmp], [
  91         AC_DEFINE(HAVE_LOGWTMP, 1, ["System provides the logwtmp() function"])
  92         AC_SUBST([UTIL_LIBS], ["-lutil"])
  93     ])
  94 ])
  95
  96 #
  97 # Check if libcrypt have crypt() function
  98 AC_CHECK_LIB([crypt], [crypt],
  99     AC_SUBST([CRYPT_LIBS], ["-lcrypt"]))
 100
 101 #
 102 # Should pppd link with -lsystemd (Linux only)
 103 AC_ARG_ENABLE([systemd],
 104     AS_HELP_STRING([--enable-systemd], [Enable support for systemd notification]))
 105 AM_CONDITIONAL(WITH_SYSTEMD, test "x${enable_systemd}" = "xyes")
 106 AM_COND_IF([WITH_SYSTEMD],
 107     AC_DEFINE([SYSTEMD], 1, [Enable support for systemd notifications]))
 108
 109 #
 110 # Enable Callback Protocol Support, disabled by default
 111 AC_ARG_ENABLE([cbcp],
 112     AS_HELP_STRING([--enable-cbcp], [Enable Callback Protocol]))
 113 AM_CONDITIONAL(WITH_CBCP, test "x${enable_cbcp}" = "xyes")
 114 AM_COND_IF([WITH_CBCP],
 115     AC_DEFINE([CBCP_SUPPORT], 1, [Have Callback Protocol support]))
 116
 117 #
 118 # Disable support for IPX control protocol
 119 AC_ARG_ENABLE([ipxcp],
 120     AS_HELP_STRING([--enable-ipxcp], [Enable IPX Control Protocol support]))
 121 AM_CONDITIONAL(WITH_IPXCP, test "x${enable_ipxcp}" = "xyes")
 122 AM_COND_IF(WITH_IPXCP,
 123     AC_DEFINE([IPX_CHANGE], 1, ["Have IPX Control Protocol"]))
 124 AS_IF([test "x${build_sunos}" = "xyes" && test "x${enable_ipxcp}" = "xyes"],
 125     [AC_MSG_ERROR([IPXCP is not supported on SunOS, disable using --disable-ipxcp])])
 126
 127 #
 128 # Disable support for limiting session duration by maximum octets
 129 AC_ARG_ENABLE([maxoctets],
 130     AS_HELP_STRING([--disable-maxoctets], [Disable support for limiting session by maximum octets]))
 131 AS_IF([test "x$enable_maxoctets" != "xno"],
 132     AC_DEFINE([MAXOCTETS], 1, ["Limit sessions by maximum number of octets"]))
 133
 134 #
 135 # Disable Microsoft extensions will remove CHAP and MPPE support
 136 AC_ARG_ENABLE([microsoft-extensions],
 137     AS_HELP_STRING([--disable-microsoft-extensions], [Disable Microsoft CHAP / MPPE extensions]))
 138
 139 AM_CONDITIONAL(WITH_CHAPMS, test "x${enable_microsoft_extensions}" != "xno")
 140 AM_COND_IF([WITH_CHAPMS],
 141     AC_DEFINE([CHAPMS], 1, ["Have Microsoft CHAP support"]))
 142
 143 AM_CONDITIONAL(WITH_MPPE, test "x${enable_microsoft_extensions}" != "xno")
 144 AM_COND_IF([WITH_MPPE],
 145     AC_DEFINE([MPPE], 1, ["Have Microsoft MPPE support"]))
 146
 147 #
 148 # Enable Microsoft LAN Manager support, depends on Microsoft Extensions
 149 AC_ARG_ENABLE([mslanman],
 150     AS_HELP_STRING([--enable-mslanman], [Enable Microsoft LAN Manager support]))
 151 AS_IF([test "x${enable_mslanman}" = "xyes" && test "x${enable_microsoft_extensions}" != "xno"],
 152     AC_DEFINE([MSLANMAN], 1, ["Have Microsoft LAN Manager support"]))
 153
 154 #
 155 # Disable IPv6 support
 156 AC_ARG_ENABLE([ipv6-support],
 157     AS_HELP_STRING([--disable-ipv6-support], [Disable IPv6 support]))
 158 AM_CONDITIONAL(WITH_INET6, test "x${enable_ipv6_support}" != "xno")
 159 AM_COND_IF([WITH_INET6],
 160     AC_DEFINE(INET6, 1, ["Have IPv6 support"]))
 161
 162 #
 163 # Disable Multilink support
 164 AC_ARG_ENABLE([multilink],
 165     AS_HELP_STRING([--enable-multilink], [Enable multilink support]))
 166 AM_CONDITIONAL(WITH_MULTILINK, test "x${enable_multilink}" = "xyes")
 167 AM_COND_IF([WITH_MULTILINK],
 168     AC_DEFINE([HAVE_MULTILINK], 1, ["Have multilink support"]))
 169 AS_IF([test "x${build_sunos}" = "xyes" && test "x${enable_multilink}" = "xyes"],
 170     [AC_MSG_ERROR([Multilink is not supported on SunOS])])
 171
 172 #
 173 # Multilink require Trivial Database Support
 174 AM_CONDITIONAL(WITH_TDB, test "x${enable_multilink}" = "xyes")
 175 AM_COND_IF([WITH_TDB],
 176     AC_DEFINE([USE_TDB], 1, ["Include TDB support"]))
 177
 178 #
 179 # Enable support for loadable plugins
 180 AC_ARG_ENABLE([plugins],
 181     AS_HELP_STRING([--disable-plugins], [Disable support for loadable plugins]))
 182 AS_IF([test "x$enable_plugins" != "xno"],
 183     AC_DEFINE([PLUGIN], 1, ["Have support for loadable plugins"]))
 184 AM_CONDITIONAL(WITH_PLUGINS, test "${enable_plugins}" != "no")
 185
 186 #
 187 # Disable EAP-TLS support
 188 AC_ARG_ENABLE([eaptls],
 189     AS_HELP_STRING([--disable-eaptls], [Disable EAP-TLS authentication support]))
 190 AS_IF([test "x$enable_eaptls" != "xno"],
 191     AC_DEFINE([USE_EAPTLS], 1, ["Have EAP-TLS authentication support"]))
 192 AM_CONDITIONAL(WITH_EAPTLS, test "${enable_eaptls}" != "no")
 193
 194 #
 195 # Disable OpenSSL engine support
 196 AC_ARG_ENABLE([openssl-engine],
 197     AS_HELP_STRING([--disable-openssl-engine], [Disable OpenSSL engine support]))
 198 AS_IF([test "x$enable_openssl_engine" != "xno"], [],
 199     AC_DEFINE([OPENSSL_NO_ENGINE], 1, ["OpenSSL engine support"]))
 200
 201 #
 202 # Specify runtime directory
 203 AC_ARG_WITH([plugin-dir],
 204         AC_HELP_STRING([--with-plugin-dir=DIR], [Specify the plugin directory for pppd]))
 205 AS_IF([test -n "$with_plugin_dir"],
 206         [PPPD_PLUGIN_DIR="$with_plugin_dir"],
 207         [PPPD_PLUGIN_DIR="${libdir}/pppd/$VERSION"])
 208 AC_SUBST(PPPD_PLUGIN_DIR, "$PPPD_PLUGIN_DIR", [The pppd plugin directory])
 209
 210 #
 211 # Specify runtime directory
 212 AC_ARG_WITH([runtime-dir],
 213         AC_HELP_STRING([--with-runtime-dir=DIR], [Specify the runtime directory for pppd]))
 214 AS_IF([test -n "$with_runtime_dir"],
 215         [PPPD_RUNTIME_DIR="$with_runtime_dir"],
 216         [PPPD_RUNTIME_DIR="${localstatedir}/run/pppd"])
 217 AC_SUBST(PPPD_RUNTIME_DIR)
 218
 219 #
 220 # Specify runtime directory
 221 AC_ARG_WITH([logfile-dir],
 222         AC_HELP_STRING([--with-logfile-dir=DIR], [Specify the log directory for pppd]))
 223 AS_IF([test -n "$with_logfile_dir"],
 224         [PPPD_LOGFILE_DIR="$with_logfile_dir"],
 225         [PPPD_LOGFILE_DIR="${localstatedir}/log/pppd"])
 226 AC_SUBST(PPPD_LOGFILE_DIR)
 227
 228 #
 229 # Check for OpenSSL
 230 AX_CHECK_OPENSSL
 231 AM_CONDITIONAL(WITH_OPENSSL, test "${with_openssl}" != "no")
 232
 233 #
 234 # Check if OpenSSL has compiled in support for various ciphers
 235 AS_IF([test "${with_openssl}" != "no" ], [
 236     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_MD4], [md4])
 237     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_MD5], [md5])
 238     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_DES], [des])
 239     AX_CHECK_OPENSSL_DEFINE([OPENSSL_NO_SHA], [sha])
 240 ], [
 241     AS_IF([test "x$enable_eaptls" != "xno"],
 242         [AC_MSG_ERROR([OpenSSL not found, and if this is your intention then run configure --disable-eaptls])])
 243 ])
 244
 245 AM_CONDITIONAL([OPENSSL_HAVE_MD4], test "x${ac_cv_openssl_md4}" = "xyes")
 246 AM_COND_IF([OPENSSL_HAVE_MD4],,
 247     AC_DEFINE([USE_MD4], 1, [Use included md4 included with pppd]))
 248
 249 AM_CONDITIONAL([OPENSSL_HAVE_MD5], test "x${ac_cv_openssl_md5}" = "xyes")
 250 AM_COND_IF([OPENSSL_HAVE_MD5],,
 251     AC_DEFINE([USE_MD5], 1, [Use included md5 included with pppd]))
 252
 253 AM_CONDITIONAL([OPENSSL_HAVE_SHA], test "x${ac_cv_openssl_sha}" = "xyes")
 254 AM_COND_IF([OPENSSL_HAVE_SHA],,
 255     AC_DEFINE([USE_SHA], 1, [Use included sha included with pppd]))
 256
 257 AM_CONDITIONAL([OPENSSL_HAVE_DES], test "x${ac_cv_openssl_des}" = "xyes")
 258 AM_COND_IF([OPENSSL_HAVE_DES],,
 259     AC_DEFINE([USE_CRYPT], 1, [Use included des included with pppd]))
 260
 261 #
 262 # If OpenSSL doesn't support DES, then use the one from libcrypt (glibc dropped support for this in 2.27).
 263 AS_IF([test "${ac_cv_openssl_des}" = "no" ], [
 264     AC_CHECK_LIB([crypt], [encrypt],
 265         [LIBS="$LIBS -lcrypt"],
 266         [AC_MSG_ERROR([OpenSSL not found or does not support DES, and libcrypt also doesn't support encrypt])]
 267     )
 268 ])
 269
 270 #
 271 # With libsrp support
 272 AX_CHECK_SRP
 273
 274 #
 275 # With libatm support
 276 AX_CHECK_ATM
 277
 278 #
 279 # With libpam support
 280 AX_CHECK_PAM(AC_DEFINE([USE_PAM], 1, ["Support for Pluggable Authentication Modules"]))
 281 AM_CONDITIONAL(WITH_PAM, test "x${with_pam}" = "xyes")
 282
 283 #
 284 # With libpcap support, activate pppd on network activity
 285 AX_CHECK_PCAP
 286
 287 #
 288 # SunOS provides a version of libpcap that would work, but SunOS has no support for activity filter
 289 AM_CONDITIONAL([WITH_FILTER], [ test "x${with_pcap}" = "xyes" && test "x${build_sunos}" != "xyes" ])
 290 AM_COND_IF([WITH_FILTER], [
 291     AC_DEFINE([PPP_FILTER], 1, ["Have packet activity filter support"])], [
 292     AS_IF([test "x${build_sunos}" = "xyes"], [
 293         AC_MSG_WARN([Packet activity filter not supported on SunOS])
 294         with_pcap="no"
 295         ])
 296     ])
 297
 298 #
 299 # Some contributions require GTK/GLIB
 300 AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk], [Build contributions with the GTK+ interface]))
 301 if test "x${with_gtk}" = "xyes"; then
 302     PKG_CHECK_MODULES([GTK], [gtk+-2.0])
 303     PKG_CHECK_MODULES([GLIB], [glib-2.0])
 304 fi
 305 AM_CONDITIONAL([WITH_GTK], test "x${with_gtk}" = "xyes")
 306
 307
 308 AC_CONFIG_FILES([
 309     Makefile
 310     chat/Makefile
 311     contrib/Makefile
 312     contrib/pppgetpass/Makefile
 313     common/Makefile
 314     include/Makefile
 315     modules/Makefile
 316     pppd/Makefile
 317     pppd/pppd.pc
 318     pppd/plugins/Makefile
 319     pppd/plugins/pppoe/Makefile
 320     pppd/plugins/pppoatm/Makefile
 321     pppd/plugins/pppol2tp/Makefile
 322     pppd/plugins/radius/Makefile
 323     pppdump/Makefile
 324     pppstats/Makefile
 325     scripts/Makefile
 326     ])
 327 AC_OUTPUT
 328
 329
 330 AS_IF([test "x${build_sunos}" = "xyes" ], [[
 331     echo "
 332 Setting up SunOS kernel module(s)"
 333     mkmkf() {
 334         rm -f $2
 335         if [ -f $1 ]; then
 336             echo "  $2 <= $1"
 337             sed -e "s,@DESTDIR@,$prefix,g" \
 338                 -e "s,@SYSCONF@,$sysconfdir,g" \
 339                 -e "s,@CC@,$CC,g" \
 340                 -e "s|@CFLAGS@|$CFLAGS|g" $1 > $2
 341         fi
 342     }
 343
 344     release=`uname -r`
 345     karch=`/usr/bin/isainfo -k`
 346     makext="sol2"
 347     archvariant=
 348
 349     case "$karch" in
 350         amd64)
 351             archvariant='-64x'
 352             ;;
 353         sparcv9)
 354             archvariant='-64'
 355             ;;
 356         *)
 357             ;;
 358     esac
 359
 360     usegcc=$CC
 361     if [ -x /opt/SUNWspro/bin/cc -a "$usegcc" != gcc ] &&
 362        /opt/SUNWspro/bin/cc -flags >/dev/null 2>&1; then
 363       if [ "$archvariant" = "-64x" ]; then
 364         ( cd /tmp; echo "int x;" > ppp$$.c
 365           /opt/SUNWspro/bin/cc -c -errwarn -xchip=opteron -m64 ppp$$.c >/dev/null 2>&1 || (
 366             echo "WorkShop C is unable to make 64 bit modules, and your $karch system needs"
 367             echo "them.  Consider upgrading cc on this machine."
 368             rm -f ppp$$.c
 369             exit 1
 370           ) || exit 1
 371           rm -f ppp$$.c ppp$$.o
 372         ) || exit 1
 373       fi
 374     elif gcc --version >/dev/null 2>&1; then
 375       archvariant=gcc$archvariant
 376       compiletype=.gcc
 377       if [ "$archvariant" = "gcc-64" -o"$archvariant" = "gcc-64x" ]; then
 378         ( cd /tmp; touch ppp$$.c
 379           gcc -c -m64 ppp$$.c >/dev/null 2>&1 || (
 380             echo "gcc is unable to make 64 bit modules, and your $karch system needs them."
 381             echo "Consider upgrading gcc on this machine, or switching to Sun WorkShop."
 382             rm -f ppp$$.c
 383             exit 1
 384           ) || exit 1
 385           rm -f ppp$$.c ppp$$.o
 386         ) || exit 1
 387       fi
 388     else
 389       echo "C compiler not found; hoping for the best."
 390     fi
 391
 392     mkmkf solaris/Makedefs$compiletype Makedefs.com
 393     mkmkf solaris/Makefile.sol2$archvariant solaris/Makefile
 394 ]])
 395
 396 echo "
 397 $PACKAGE_NAME version $PACKAGE_VERSION
 398     Prefix...............: $prefix
 399     Runtime Dir..........: $PPPD_RUNTIME_DIR
 400     Logfile Dir..........: $PPPD_LOGFILE_DIR
 401     Plugin Dir...........: $PPPD_PLUGIN_DIR
 402     With OpenSSL.........: ${with_openssl:-yes}
 403     With libatm..........: ${with_atm:-no}
 404     With libpam..........: ${with_pam:-no}
 405     With libpcap.........: ${with_pcap:-no}
 406     With libsrp..........: ${with_srp:-no}
 407     C Compiler...........: $CC $CFLAGS
 408     Linker...............: $LD $LDFLAGS $LIBS
 409
 410 Features enabled
 411     Microsoft Extensions.: ${enable_microsoft_extensions:-yes}
 412     Multilink............: ${enable_multilink:-no}
 413     Plugins..............: ${enable_plugins:-yes}
 414     CBCP.................: ${enable_cbcp:-no}
 415     IPXCP................: ${enable_ipxcp:-no}
 416     EAP-TLS..............: ${enable_eaptls:-yes}
 417 "