+AS_IF(
+ [test "x$with_twin_x11" = "xyes"],
+ [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $twin_CFLAGS"
+ AC_CHECK_HEADERS(
+ [libtwin/twin_x11.h],
+ [],
+ [AC_MSG_FAILURE([ --with-twin-x11 given but libtwin/twin_x11.h not found])]
+ )
+ CPPFLAGS="$SAVE_CPPFLAGS"
+ ]
+)
+
+AS_IF(
+ [test "x$with_twin_fbdev" = "xyes"],
+ [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $twin_CFLAGS"
+ AC_CHECK_HEADERS(
+ [libtwin/twin_fbdev.h],
+ [],
+ [AC_MSG_FAILURE([ --with-twin-fbdev given but libtwin/twin_fbdev.h not found])]
+ )
+ CPPFLAGS="$SAVE_CPPFLAGS"
+ ]
+)
+
+AC_ARG_WITH(
+ [signed-boot],
+ [AS_HELP_STRING([--with-signed-boot=@<:@no|yes|gpgme|openssl@:>@],
+ [Build kernel signature checking support with specified
+ crypto pacakge. A @<:@yes@:>@ value will first check
+ for gpgme then openssl and use the first found.
+ @<:@default=no@:>@]
+ )],
+ [AS_IF([test "x$with_signed_boot" = xno],[],
+ [test "x$with_signed_boot" = xyes],
+ [AM_PATH_GPGME([1.0.0],
+ [sboot=gpgme],
+ [AX_CHECK_OPENSSL(
+ [sboot=openssl],
+ [AC_MSG_FAILURE([--with-signed-boot=yes specified but gpgme or openssl not found])]
+ )]
+ )],
+ [test "x$with_signed_boot" = xgpgme],
+ [AM_PATH_GPGME([1.0.0],
+ [sboot=gpgme],
+ [AC_MSG_FAILURE([--with-signed-boot=gpgme specified but gpgme not found])]
+ )],
+ [test "x$with_signed_boot" = xopenssl],
+ [AX_CHECK_OPENSSL(
+ [sboot=openssl],
+ [AC_MSG_FAILURE([--with-signed-boot=openssl specified but openssl not found])]
+ )],
+ [AC_MSG_FAILURE([--with-signed-boot given invalid option: $with_signed_boot])]
+ )],
+ [with_signed_boot=no]
+)
+
+AM_CONDITIONAL([WITH_GPGME], [test "x$sboot" = xgpgme])
+AM_CONDITIONAL([WITH_OPENSSL], [test "x$sboot" = xopenssl])
+AM_CONDITIONAL([WITH_SIGNED_BOOT], [test "x$with_signed_boot" != xno])
+AM_COND_IF([WITH_SIGNED_BOOT],
+ [AC_DEFINE([SIGNED_BOOT], 1, [Define if you have signed boot enabled])],
+ [])
+
+AC_ARG_VAR(
+ [lockdown_file],
+ [Location of authorized signature file [default = "/etc/pb-lockdown"]]
+)
+AS_IF([test "x$lockdown_file" = x], [lockdown_file="/etc/pb-lockdown"])
+AC_DEFINE_UNQUOTED(LOCKDOWN_FILE, "$lockdown_file", [Lockdown file location])
+
+AC_ARG_VAR(
+ [KEYRING_PATH],
+ [Path to keyring (gpgme home dir) @<:@default="/etc/gpg"@:>@]
+)
+AS_IF([test "x$KEYRING_PATH" = x], [KEYRING_PATH="/etc/gpg"])
+AC_DEFINE_UNQUOTED(KEYRING_PATH, "$KEYRING_PATH", [gpgme home dir])
+
+AC_ARG_VAR(
+ [VERIFY_DIGEST],
+ [Signed boot signature verification digest algorithm to use (only valid in openssl) @<:@default="sha256"@:>@]
+)
+AS_IF([test "x$VERIFY_DIGEST" = x], [VERIFY_DIGEST="sha256"])
+AC_DEFINE_UNQUOTED(VERIFY_DIGEST, "$VERIFY_DIGEST", [openssl verify dgst])
+
+AC_ARG_ENABLE([hard-lockdown],
+ [AS_HELP_STRING([--enable-hard-lockdown],
+ [if signed boot configured, the absence of the
+ LOCKDOWN_FILE does not disable signed boot at
+ runtime @<:@default=no@:>@])],
+ [AC_DEFINE(HARD_LOCKDOWN, 1, [Enable hard lockdown])],
+ [])
+
+AC_ARG_ENABLE(
+ [busybox],
+ [AS_HELP_STRING(
+ [--enable-busybox],
+ [build programs with extra support for busybox [default=no]])
+ ],
+ [],
+ [enable_busybox=no]
+)
+AM_CONDITIONAL([ENABLE_BUSYBOX], [test "x$enable_busybox" = "xyes"])
+AS_IF([test "x$enable_busybox" = "xyes"],
+ [AC_DEFINE(WITH_BUSYBOX, 1, [Busybox environment enabled])],
+ []
+)
+
+AC_ARG_ENABLE(
+ [mtd],
+ [AS_HELP_STRING(
+ [--enable-mtd],
+ [Add support for MTD devices on certain platforms [default=no]]
+ )],
+ [],
+ [enable_mtd=no]
+)
+AM_CONDITIONAL([ENABLE_MTD], [test "x$enable_mtd" = "xyes"])
+AS_IF([test "x$enable_mtd" = "xyes"],
+ [AC_DEFINE(MTD_SUPPORT, 1, [Enable MTD support])],
+ []
+)
+
+AS_IF(
+ [test "x$enable_mtd" = "xyes"],
+ AC_CHECK_LIB([flash], [arch_flash_init],
+ [LIBFLASH_LIBS=-lflash],
+ [AC_MSG_FAILURE([--enable-mtd requires the libflash library])]
+ )
+)
+AS_IF(
+ [test "x$enable_mtd" = "xyes"],
+ [SAVE_CPPFLAGS="$CPPFLAGS" CPPFLAGS="$CPPFLAGS $libflash_CFLAGS"
+ AC_CHECK_HEADERS(
+ [libflash/libflash.h],
+ [],
+ [AC_MSG_FAILURE([--enable-mtd given but libflash/libflash.h not found])]
+ )
+ CPPFLAGS="$SAVE_CPPFLAGS"
+ ]
+)
+
+AC_ARG_ENABLE(
+ [ps3],
+ [AS_HELP_STRING(
+ [--enable-ps3],
+ [build additional programs for the PS3 game console [default=no]]
+ )],
+ [],
+ [enable_ps3=no]
+)
+AM_CONDITIONAL([ENABLE_PS3], [test "x$enable_ps3" = "xyes"])
+
+AC_ARG_ENABLE(
+ [debug],
+ [AS_HELP_STRING([--enable-debug],
+ [build programs with extra debug info [default=no]]
+ )],
+ [],
+ [enable_debug=check]
+)
+#AM_CONDITIONAL([ENABLE_DEBUG], [test "x$enable_debug" = "xyes"])
+
+AC_ARG_ENABLE(
+ [test-valgrind],
+ [AS_HELP_STRING([--enable-test-valgrind],
+ [run all tests with valgrind]
+ )],
+)
+AM_CONDITIONAL([ENABLE_TEST_VALGRIND], [test "x$enable_test_valgrind" = "xyes"])
+
+# host program paths
+AC_DEFUN([DEFINE_HOST_PROG],
+ [
+ AC_ARG_VAR([HOST_PROG_$1], [Path to "$2" on the host [default $3]])
+ if test "x$HOST_PROG_$1" = "x"; then
+ HOST_PROG_$1="$3"
+ fi
+ AC_DEFINE_UNQUOTED(HOST_PROG_$1, ["$HOST_PROG_$1"],
+ [Path to "$2" on the host])
+ ])
+
+DEFINE_HOST_PROG(CP, cp, [/bin/cp])
+DEFINE_HOST_PROG(KEXEC, kexec, [/sbin/kexec])
+DEFINE_HOST_PROG(MOUNT, mount, [/bin/mount])
+DEFINE_HOST_PROG(SHUTDOWN, shutdown, [/sbin/shutdown])
+DEFINE_HOST_PROG(SFTP, sftp, [/usr/bin/sftp])
+DEFINE_HOST_PROG(TFTP, tftp, [/usr/bin/tftp])
+DEFINE_HOST_PROG(UMOUNT, umount, [/bin/umount])
+DEFINE_HOST_PROG(WGET, wget, [/usr/bin/wget])
+DEFINE_HOST_PROG(IP, ip, [/sbin/ip])
+DEFINE_HOST_PROG(UDHCPC, udhcpc, [/sbin/udhcpc])
+DEFINE_HOST_PROG(VGSCAN, vgscan, [/usr/sbin/vgscan])
+DEFINE_HOST_PROG(VGCHANGE, vgchange, [/usr/sbin/vgchange])
+DEFINE_HOST_PROG(PB_PLUGIN, pb-plugin, [/usr/sbin/pb-plugin])
+DEFINE_HOST_PROG(PB_EXEC, pb-exec, [/usr/sbin/pb-exec])
+DEFINE_HOST_PROG(SH, sh, [/bin/sh])
+DEFINE_HOST_PROG(SCSI_RESCAN, scsi-rescan, [/usr/sbin/scsi-rescan])
+
+AC_ARG_WITH(
+ [tftp],
+ [AS_HELP_STRING([--with-tftp=TYPE],
+ [Use TYPE-type ftp client (either hpa or busybox) [default=runtime-check]]
+ )],
+ [],
+ [with_tftp=detect]
+)
+
+case x$with_tftp in
+'xhpa')
+ tftp_type='TFTP_TYPE_HPA'
+ ;;
+'xbusybox')
+ tftp_type='TFTP_TYPE_BUSYBOX'
+ ;;
+*)
+ tftp_type='TFTP_TYPE_UNKNOWN'
+ ;;
+esac
+
+AC_DEFINE_UNQUOTED(TFTP_TYPE, $tftp_type, [tftp client type])
+
+default_cflags="--std=gnu99 -g \
+ -Wall -W -Wunused -Wstrict-prototypes -Wmissing-prototypes \
+ -Wmissing-declarations -Wredundant-decls"
+
+AC_ARG_ENABLE(
+ [werror],
+ [AS_HELP_STRING([--enable-werror],
+ [build programs with -Werror]
+ )],
+ [default_cflags="$default_cflags -Werror"]
+)
+
+AS_IF(
+ [test "x$enable_debug" = "xyes"],
+ [
+ AC_SUBST([DEFAULT_CFLAGS], ["$default_cflags -O0"])
+ AC_SUBST([DEFAULT_CPPFLAGS], ["-DDEBUG"])
+ ],
+ [
+ AC_SUBST([DEFAULT_CFLAGS], ["$default_cflags -O2"])
+ AC_SUBST([DEFAULT_CPPFLAGS], ["-DNDEBUG"])
+ ]
+)
+
+AC_SUBST([UDEV_LIBS])
+AC_SUBST([DEVMAPPER_LIBS])
+AC_SUBST([FDT_LIBS])
+AC_SUBST([LIBFLASH_LIBS])
+AC_SUBST([LIBTOOL_DEPS])
+AC_SUBST([DESTDIR])
+AC_SUBST([pkgsysconfdir], ["${sysconfdir}/${package}"])
+
+AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_FILES([
+ Makefile
+ po/Makefile.in
+])